#include <EEPROM.h>
  boolean DPPA = 0, dppa_tmp = 0;                         //Флаги педали газа: 0 - педаль не нажата, 1 - педаль нажата
  boolean DS = 0, ds_tmp = 0;                             //Флаги датчика скорости: 0 - скорость недостаточна, 1 - скорость в норме
  int DRL = 2; boolean drl_tmp = 0;                       //Флаги ДХО: 0 - выключено, 1 - включено, 2 - режим ожидания (авторежим)
  boolean ESW = 0, esw_tmp = 0;                           //Флаги состояние коцевика дверей: 0 - двери открыты, 1 - закрыты
  boolean LOCK = 0, lock_tmp =0;                          //Флаги запертых дверей: 0 - двери незаперты, 1 - заперты
  byte UPR;                                               //Флаг управлением дверей: 0 - не управлять, 1 - управлять (хранится в ЕЕПРОМ)
  boolean BOTTON = 0, botton_tmp = 0, bot_fl = 0;         //Положение и флаги кнопки: 0 - ненажата, 1 - нажата
  int Press = 0;                                          //Отклик кнопки: 0 - не нажата, 1 - короткое нажатие, 2 - длинное нажатие
  volatile unsigned long time_hz = 0;                     //Время предудущего прерывания датчика скорости
  volatile unsigned int HZ = 0;                           //Частота датчика скорости
  unsigned long time_esw = 0, time_dppa = 0, time_ds = 0, time_drl = 0, time_botton = 0, time_BOTTON = 0, time_upr = 0;//Засечки времени
                                     
  void setup() {                                          //Вход педали газа на А0
    pinMode(19, INPUT);                                   //Вход кнопки управления А5(Д19): 0 - нажата, 1 - отпущена (инвертированная)
    pinMode(16, INPUT);                                   //Вход концевика дверей А2(Д16): 0 - двери открыты, 1 - закрыты
    pinMode(10, OUTPUT);                                  //Выходной сигнал на закрытие Д10
    pinMode(17, OUTPUT);                                  //Выходной сигнал на ДХО А3(Д17)
    attachInterrupt(1, Speed, RISING);                    //Прерывание по датчику скорости, пин Д3
    UPR = EEPROM.read(0);                                 //Считать флаг управления дверей.
  }
 
/***Мониторит концевик и все датчики в реальном времени***/
  void loop() {
    if(micros()-time_hz > 1000000) HZ = 0;                //Если с датчика скорости больше секунды не было отклика, скорость нулевая
    Bounce_DS(20<HZ && HZ<300);                           //Проверка датчика скорости на установку флага для запирания (12км/ч-180км/ч, HZ = V*6/3.6)
    if(DRL==2) Bounce_DRL(10<HZ && HZ<300);               //Проверка датчика скорости в режиме ожидания для ДХО (6км/ч-180км/ч, HZ = V*6/3.6)   
    Bounce_ESW(digitalRead(16));                          //Считываем концевик и проверяем на дребезг     
    Bounce_Botton(!digitalRead(19));                      //Считываем кнопку (с инверсией) и проверяем на дребезг
    Bounce_DPPA(analogRead(0) > 140);                     //Проверка педали газа на установку флага (0,78V->1,03V 105+35)
 
    if(Press == 2) {                                      //Если было длинное нажатие,
      UPR = !UPR;                                         //переключить управление ЦЗ
      EEPROM.write(0, UPR);                               //и запомнить.
      if(DRL==1) {                                        //Если ДХО включены,
        digitalWrite(17, 0);                              //моргнуть выключением на 0,5 сек.
        delay(500);
        digitalWrite(17, 1);                           
        delay(500);
      }
      else {                                              //Если ДХО выключены,
        digitalWrite(17, 1);                              //моргнуть включением на 0,5 сек.
        delay(500);                                       
        digitalWrite(17, 0);                           
        delay(500);
      }
    }
 
    if(Press == 1){                                       //Если было короткое нажатие,
      if(DRL==1 && HZ==0){                                //если ДХО включены и скорость нулевая,
        DRL = 2;                                          //перевести ДХО в автоматический режим и
        digitalWrite(17, 0);                              //выключить ДХО
      }
      else{                                               
        if(DRL==2) DRL = 1;                               //включить ДХО если был режим ожидания,
        else DRL = !DRL;                                  //инвертировать ДХО в ручном режиме 
        digitalWrite(17, DRL);                            //и подать соответсвующий сигнал на выход ДХО
      }
    }
 
    if(!ESW) LOCK = 0;                                    //Если двери открыты, то они не заперты         
    if(ESW && !LOCK && DPPA && DS && UPR) Zakrdv();       //Если двери закрыты, не заперты, выставлены флаги датчиков и управления, то запереть двери
  }
 
/***Пытается запереть двери при благоприятных условиях***/
  void Zakrdv() {                                         //Процесс запирание
    unsigned long time_zakr = millis();                   //Поставить засечку времени.
    while(millis()-time_zakr < 500){                      //Полсекундная задержка на полное защелкивание замков (если двери закрылись на ходу)
      Bounce_ESW(digitalRead(16));                        //Продолжаем мониторить концевик
      if(!ESW) return;                                    //Резет, если двери открылись внезапкно
    }
    digitalWrite(10, 1);                                 
    delay(200);                                           //Подать импульс 0,2 сек. на запирание
    digitalWrite(10, 0);                               
    LOCK = 1;                                             //Выставить флаг запертости.
    time_zakr = millis();                                 //Обновить засечку времени.     
    while(millis()-time_zakr < 1500){                     //Подождать запирание дверей 1,5 секунды (из-за ступенчатой работы активаторов)
      Bounce_ESW(digitalRead(16));                        //Продолжаем мониторить концевик
      if(!ESW) LOCK = 0;                                  //Сбросить флаг, если двери открылись сразу за закрытием
    }
  }
 
/***Мониторит скорость в реальном времени***/
  void Speed() {                               
    HZ = 1000000/(micros() - time_hz);                    //Определение частоты датчика скорости
    time_hz = micros();                                   //Засечка времени
  }
 
/***Проверка дребезга двери двухстороняя***/
  void Bounce_ESW(boolean tmp) {                          //Проверка дребезга концевика в течении 1/4 сек.
    if (tmp != esw_tmp){                                  //Если прошла инвертация, то
      esw_tmp = tmp;                                      //запомнить текущее состояние (временный флаг),
      time_esw = millis();                                //поставить засечку времени.
    }
    else
      if (millis()-time_esw > 250){                       //Если прошло больше четверти секунды без инвертаций, то
        ESW = esw_tmp = tmp;                              //записать значение флага концевика (стабильное и временное).
      }
  }
 
/***Кнопка***/
  void Bounce_Botton (boolean tmp) {                      //Кнопка возвращает однократно: 1 - короткое нажатие, 2 - длинное, 0 - не нажата
    Press = 0;                                            //По умолчанию не нажата         
    if (tmp != botton_tmp){                               //Если прошла инвертация, то
      botton_tmp = tmp;                                   //запомнить текущее состояние (временный флаг),
      time_botton = millis();                             //поставить засечку времени (временную инвертации).
    }
    else                                                 
      if (millis()-time_botton > 50){                     //Если прошло больше 50 мс без инвертаций, и
        if (BOTTON != tmp){                               //1. Если предыдущее положение кнопки отличается от текущего (т.е. было нажатие, а не дребезг), и
          if (millis()-time_BOTTON < 500 && BOTTON)       //предыдущая инвертация была меньше 0,5 сек. и инвертация была нажатием, то
            Press = 1;                                    //было короткое нажатие.
          BOTTON = tmp;                                   //запомнить текущее положение кнопки
          time_BOTTON = millis();                         //обновить засечку времени стабильной инвертации
          bot_fl=1;                                       //поставить "флаг длительного нажатия"
        }
        if (millis()-time_BOTTON > 1000 && BOTTON && bot_fl){   //2. Если кнопка удерживается дольше 1 сек в положении нажатия и флаг разрешает длительное нажатие
          Press = 2;                                      //было длинное нажатие
          bot_fl = 0;                                     //сбросить "флаг длительного нажатия", чтобы функция повторно не возвращала 2
        }
      }
  }
 
/***Проверка дребезга педали газа на стабильный положительный отклик***/
  void Bounce_DPPA (boolean tmp) {                        //Проверка педали газа в течении 1/4 сек.
    if(!tmp){                                             //При отрицательном отклике,                                       
      DPPA = dppa_tmp = 0;                                //обнулить флаги,
      return;                                             //и выйти.
    }
    if (tmp > dppa_tmp){                                  //Если прошел положительный фронт,
      dppa_tmp = 1;                                       //поднять временный флаг,
      time_dppa = millis();                               //поставить засечку времени.
    }
    else                                                  //Если идут непрерывные положительные отклики,
      if (millis()-time_dppa > 250) DPPA = 1;             //и, если прошло больше четверти секунды, поднять основной флаг.
  }
 
/***Проверка дребезга датчика скорости на стабильный положительный отклик***/   
  void Bounce_DS (boolean tmp) {                          //Проверка стабильности ДС в течении 1/2 сек.
    if(!tmp){                                             //При отрицательном отклике,
      DS = ds_tmp = 0;                                    //обнулить флаги,
      return;                                             //и выйти.
    }
    if (tmp > ds_tmp){                                    //Если прошел положительный фронт,
      ds_tmp = 1;                                         //поднять временный флаг,
      time_ds = millis();                                 //поставить засечку времени.
    }
    else                                                  //Если идут непрерывные положительные отклики,
      if (millis()-time_ds > 500) DS = 1;                 //и, если прошло больше пол секунды, поднять основной флаг.
  }
 
/***Проверка дребезга датчика скорости на стабильный положительный отклик***/   
  void Bounce_DRL (boolean tmp) {                         //Проверка стабильности ДС в течении 1/2 сек.
    if(!tmp){                                             //При отрицательном отклике,
      drl_tmp = 0;                                        //обнулить флаг,
      return;                                             //и выйти.
    }
    if (tmp > drl_tmp){                                   //Если прошел положительный фронт,
      drl_tmp = 1;                                        //поднять временный флаг,
      time_drl = millis();                                //поставить засечку времени.
    }
    else                                                  //Если идут непрерывные положительные отклики,
      if (millis()-time_drl > 500) {                      //и, если прошло больше пол секунды,
        DRL = 1;                                          //поднять основной флаг (больше к функции обращения не будет),
        digitalWrite(17, 1);                              //и зажечь ДХО.
      }
  }